Windows 10: Ghim phân vùng và ổ cứng vào Navigation Bar trong File Explorer

Về mặt kỹ thuật, Navigation Bar (thanh điều hướng) của File Explorer (hay còn gọi là Windows Explorer trên các phiên bản Windows cũ) cung cấp “sơ đồ”, giúp người dùng định hướng và dễ dàng truy cập đến mọi thư mục, phân vùng, ổ cứng có thể truy xuất trên hệ thống.

Không chỉ vậy, kể từ “thời” Windows 10, ngoài những mục được hiển thị mặc định như This PC, Network,Quick Access,.. Microsoft đã cho phép người dùng có thể ghim (Pin) thêm một số thư mục cụ thể khác vào thanh Navigation Bar nhằm giúp việc truy cập đến các thư mục này được nhanh hơn.

Với các phân vùng, ổ cứng, chúng chỉ có thể được truy cập đến khi bạn mở rộng This PC. Nhưng nếu đang tìm cách để ghim chúng vào thanh Navigation Bar (tương tự các mục mặc định Quick Acces,This PC,..) thì dưới đây là cách để bạn thực hiện điều này.

Trước khi tiến hành thực hiện, bạn cần phải sao lưu (backup) một khóa Registry hệ thống, qua đó bạn có thể phục hồi khóa này về trạng thái trước khi thực hiện. Để thực hiện, bạn hãy nhấn phím tắt Windows + R, nhập từ khóa Regedit trong hộp thoại vừa xuất hiện và nhấn Enter.

Trong cửa sổ Registry Editor, hãy truy cập theo từ đường dẫn

HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\HideDesktopIcons\NewStartPanel

Nếu đã nâng cấp Windows 10 lên phiên bản mới nhất (tức bản 1809), bạn có thể sử dụng khung tìm kiếm của Registry Editor để thao tác được nhanh hơn. Sau khi tìm đến, hãy nhấn phải chuột vào khóa NewStartPanel, chọn Export, chọn vị trí mình muốn lưu trữ an toàn khóa này là hoàn tất.

Bước tiếp theo, bạn hãy mở Notepad bằng cách nhập từ khóa notepad vào thanh tìm kiếm Search bar của Windows. Trong giao diện soạn thảo, bạn hãy sao chép và dán đoạn mã (script) dưới đây, sau đó lưu lại thành tên theo ý mình với định dạng .bat

@ECHO OFF
SETLOCAL EnableExtensions
set "_icon=%%SystemRoot%%\system32\imageres.dll,27"
set "_name=D DataDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"
set "_target=d:\\"

set "_regK=HKCU\Software\Classes\CLSID"
set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"
if NOT "%~1"=="" goto :deleAll
reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f
reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f
reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f
reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add %_regE%\Desktop\NameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /t REG_DWORD /d 0x1 /f

:endlocal
ENDLOCAL
goto :eof

:deleAll
reg delete %_regK%\{%_guid%} /f
reg delete %_regE%\Desktop\NameSpace\{%_guid%} /f
reg delete %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /f
goto :endlocal

Khi khởi chạy tập tin .bat vừa tạo trên, lập tức phân vùng D:\ sẽ được hiển thị bên ngoài mục This PC trên thanh Navigation Bar. Qua đó, bạn có thể tối ưu hóa thao tác truy cập đến phân vùng này so với trước.

Để bổ sung thêm các phân vùng, ổ cứng khác, bạn chỉ cần chỉnh sửa 3 dòng lệnh sau đây:

set "_name=D DataDisk"	là tên phân vùng, ổ cứng sẽ hiển thị trên thanh Navigation Bar, bạn có thể thay đổi “D DataDisk” thành một tên tùy ý, nhưng hãy đảm bảo rằng chúng tuân theo các quy tắc của Windows, ví dụ “USB_ABC,..”
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"	Chữ cái cuối cùng của lệnh cho phép thay đổi thành 5 chữ cái khác là a,b,c,d,e,f tương ứng với 5 phân vùng, ổ cứng có thể được bổ sung vào thanh Navigation Bar.
set "_target=d:\\"	là phân vùng, ổ cứng được chọn để hiển thị.

Lấy ví dụ: để bổ sung thêm phân vùng C:\, các lệnh này được chỉnh sửa như sau

set "_name=C System Disk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000c"
set "_target=c:\\"

Lưu ý, khi thêm nhiều phân vùng, ổ cứng vào thanh Navigation Bar, bạn nên tạo từng tập tin .bat riêng biệt tương ứng với các phân vùng, ổ cứng mình muốn thêm thay vì chỉ chỉnh sửa lệnh trên tập tin .bat chính. Điều này giúp việc gỡ bỏ chúng khi không cần trở nên đơn giản hơn.

Để gỡ bỏ phân vùng, ổ cứng đã thêm này, bạn hãy khởi chạy Command Prompt ở quyền quản trị viên (Administrator), bằng cách nhập từ khóa Command Prompt vào thanh Search bar của Windows, nhấn phải chuột vào kết quả vừa hiển thị, chọn Run as Administrator.

Trong giao diện dòng lệnh, bạn nhập lệnh CD “đường dẫn đến tập tin .bat”. Bạn có thể lấy đường dẫn của tập tin này bằng cách nhấn phải chuột và chọn Properties. Trong cửa sổ Properties, tại thẻ General, bạn sao chép đường dẫn ở mục Location và dán vào giao diện dòng lệnh Command Prompt, sau đó nhấn Enter. Lấy ví dụ, chúng tôi lưu tập tin này ngoài màn hình desktop, nên đường dẫn sẽ có cấu trúc CD C:\Users\DucNT\Desktop

Tiếp đến, bạn nhập lệnh Tên_tập_tin.bat x

Trong đó, cụm Tên_tập_tin.bat chính là tên của tập tin .bat tương ứng với phân vùng, ổ cứng mình muốn gỡ.